好的就加分，其實我也是收藏別人的
嵌入式系統>51單片機浮點運算子程序庫
1: FSDT 功能:浮點數格式化
2: FADD 功能:浮點數加法
3: FSUB 功能:浮點數減法
4: FMUL 功能:浮點數乘法
5: FDIV 功能:浮點數除法
6: FCLR 功能:浮點數清零
7: FZER 功能:浮點數判零
8: FMOV 功能:浮點數傳送
9: FPUS 功能:浮點數壓棧
10: FPOP 功能:浮點數出棧
11: FCMP 功能:浮點數代數值比較不影響待比較操作數
12: FABS 功能:浮點絕對值函數
13: FSGN 功能:浮點符號函數
14: FINT 功能:浮點取整函數
15: FRCP 功能:浮點倒數函數
16: FSQU 功能:浮點數平方
17: FSQR 功能:浮點數開平方快速逼近算法
18: FPLN 功能:浮點數多項式計算
19: FLOG 功能:以10為底的浮點對數函數
20: FLN 功能:以e為底的浮點對數函數
21: FE10 功能:以10為底的浮點指數函數
22: FEXP 功能:以e為底的浮點指數函數
23: FE2 功能:以2為底的浮點指數函數
24: DTOF 功能:雙字節十六進制定點數轉換成格式化浮點數
25: FTOD 功能:格式化浮點數轉換成雙字節定點數
26: BTOF 功能:浮點BCD碼轉換成格式化浮點數
27: FTOB 功能:格式化浮點數轉換成浮點BCD碼
28: FCOS 功能:浮點余弦函數
29: FSIN 功能:浮點正弦函數
30: FATN 功能:浮點反正切函數
31: RTOD 功能:浮點弧度數轉換成浮點度數
32: DTOR 功能:浮點度數轉換成浮點弧度數
為便於讀者使用本程序庫,先將有關約定說明如下:
1.雙字節定點操作數:用[R0]或[R1]來表示存放在由R0或R1指示的連續單元中的數據,地址小的單元存放高字節?如果[R0]=1234H,若(R0)=30H,則(30H)=12H,(31H)=34H?
2.二進制浮點操作數:用三個字節表示,第壹個字節的最高位為數符,其余七位為階碼(補碼形式),第二字節為尾數的高字節,第三字節為尾數的低字節,尾數用雙字節純小數(原碼)來表示?當尾數的最高位為1時,便稱為規格化浮點數,簡稱操作數?在程序說明中,也用[R0]或[R1]來表示R0或R1指示的浮點操作數,例如:當[R0]=-6.000時,則二進制浮點數表示為83C000H?若(R0)=30H,則(30H)=83H,(31H)=0C0H,(32H)=00H?
3.十進制浮點操作數:用三個字節表示,第壹個字節的最高位為數符,其余七位為階碼(二進制補碼形式),第二字節為尾數的高字節,第三字節為尾數的低字節,尾數用雙字節BCD碼純小數(原碼)來表示?當十進制數的絕對值大於1時,階碼就等於整數部分的位數,如 876.5 的階碼是03H,-876.5 的階碼是 83H;當十進制數的絕對值小於1時,階碼就等於 80H 減去小數點後面零的個數,例如 0.00382 的階碼是 7EH,-0.00382的階碼是 0FEH?在程序說明中,用[R0]或[R1]來表示R0或R1指示的十進制浮點操作數?例如有壹個十進制浮點操作數存放在30H?31H?32H中,數值是 -0.07315,即-0.7315乘以10的-1次方,則(30H)=0FFH,31H=73H,(32H)=15H?若用[R0]來指向它,則應使(R0)=30H?
4.運算精度:單次定點運算精度為結果最低位的當量值;單次二進制浮點算術運算的精度優於十萬分之三;單次二進制浮點超越函數運算的精度優於萬分之壹;BCD碼浮點數本身的精度比較低(萬分之壹到千分之壹),不宜作為運算的操作數,僅用於輸入或輸出時的數制轉換?不管那種數據格式,隨著連續運算的次數增加,精度都會下降?
5.工作區:數據工作區固定在A?B?R2~R7,數符或標誌工作區固定在PSW和23H單元(位1CH~1FH)?在浮點系統中,R2?R3?R4和位1FH為第壹工作區,R5?R6?R7和位1EH為第二工作區?用戶只要不在工作區中存放無關的或非消耗性的信息,程序就具有較好的透明性?
6.子程序調用範例:由於本程序庫特別註意了各子程序接口的相容性,很容易采用積木方式(或流水線方式)完成壹個公式的計算?以浮點運算為例:
計算 y = Ln √ | Sin (ab/c+d) |
已知:a=-123.4;b=0.7577;c=56.34;d=1.276; 它們分別存放在30H?33H?36H?39H開始的連續三個單元中?用BCD碼浮點數表示時,分別為a=831234H;b=007577H;c=025634H;d=011276H?
求解過程:通過調用BTOF子程序,將各變量轉換成二進制浮點操作數,再進行各
種運算,最後調用FTOB子程序,還原成十進制形式,供輸出使用?程序如下:
TEST: MOV R0,#39H ;指向BCD碼浮點操作數d
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#36H ;指向BCD碼浮點操作數c
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#33H ;指向BCD碼浮點操作數b
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R0,#30H ;指向BCD碼浮點操作數a
LCALL BTOF ;將其轉換成二進制浮點操作數
MOV R1,#33H ;指向二進制浮點操作數b
LCALL FMUL ;進行浮點乘法運算
MOV R1,#36H ;指向二進制浮點操作數c
LCALL FDIV ;進行浮點除法運算
MOV R1,#39H ;指向二進制浮點操作數d
LCALL FADD ;進行浮點加法運算
LCALL FSIN ;進行浮點正弦運算
LCALL FABS ;進行浮點絕對值運算
LCALL FSQR ;進行浮點開平方運算
LCALL FLN ;進行浮點對數運算
LCALL FTOB ;將結果轉換成BCD碼浮點數
STOP: LJMP STOP
END
運行結果,[R0]=804915H,即y=-0.4915,比較精確的結果應該是-0.491437?
(1) 標號: FSDT 功能:浮點數格式化
入口條件:待格式化浮點操作數在[R0]中?
出口信息:已格式化浮點操作數仍在[R0]中?
影響資源:PSW?A?R2?R3?R4?位1FH 堆棧需求: 6字節
FSDT: LCALL MVR0 ;將待格式化操作數傳送到第壹工作區中
LCALL RLN ;通過左規完成格式化
LJMP MOV0 ;將已格式化浮點操作數傳回到[R0]中
(2) 標號: FADD 功能:浮點數加法
入口條件:被加數在[R0]中,加數在[R1]中?
出口信息:OV=0時,和仍在[R0]中,OV=1時,溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求: 6字節
FADD: CLR F0 ;設立加法標誌
SJMP AS ;計算代數和
(3) 標號: FSUB 功能:浮點數減法
入口條件:被減數在[R0]中,減數在[R1]中?
出口信息:OV=0時,差仍在[R0]中,OV=1時,溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求:6字節
FSUB: SETB F0 ;設立減法標誌
AS: LCALL MVR1 ;計算代數和?先將[R1]傳送到第二工作區
MOV C,F0 ;用加減標誌來校正第二操作數的有效符號
RRC A
XRL A,@R1
MOV C,ACC.7
ASN: MOV 1EH,C ;將第二操作數的有效符號存入位1EH中
XRL A,@R0 ;與第壹操作數的符號比較
RLC A
MOV F0,C ;保存比較結果
LCALL MVR0 ;將[R0]傳送到第壹工作區中
LCALL AS1 ;在工作寄存器中完成代數運算
MOV0: INC R0 ;將結果傳回到[R0]中的子程序入口
INC R0
MOV A,R4 ;傳回尾數的低字節
MOV @R0,A
DEC R0
MOV A,R3 ;傳回尾數的高字節
MOV @R0,A
DEC R0
MOV A,R2 ;取結果的階碼
MOV C,1FH ;取結果的數符
MOV ACC.7,C ;拼入階碼中
MOV @R0,A
CLR ACC.7 ;不考慮數符
CLR OV ;清除溢出標誌
CJNE A,#3FH,MV01;階碼是否上溢?
SETB OV ;設立溢出標誌
MV01: MOV A,@R0 ;取出帶數符的階碼
RET
MVR0: MOV A,@R0 ;將[R0]傳送到第壹工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1FH中
MOV 1FH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R2,A ;存放在R2中
INC R0
MOV A,@R0 ;將尾數高字節存放在R3中
MOV R3,A
INC R0
MOV A,@R0 ;將尾數低字節存放在R4中
MOV R4,A
DEC R0 ;恢復數據指針
DEC R0
RET
MVR1: MOV A,@R1 ;將[R1]傳送到第二工作區中的子程序
MOV C,ACC.7 ;將數符保存在位1EH中
MOV 1EH,C
MOV C,ACC.6 ;將階碼擴充為8bit補碼
MOV ACC.7,C
MOV R5,A ;存放在R5中
INC R1
MOV A,@R1 ;將尾數高字節存放在R6中
MOV R6,A
INC R1
MOV A,@R1 ;將尾數低字節存放在R7中
MOV R7,A
DEC R1 ;恢復數據指針
DEC R1
RET
AS1: MOV A,R6 ;讀取第二操作數尾數高字節
ORL A,R7
JZ AS2 ;第二操作數為零,不必運算
MOV A,R3 ;讀取第壹操作數尾數高字節
ORL A,R4
JNZ EQ1
MOV A,R6 ;第壹操作數為零,結果以第二操作數為準
MOV R3,A
MOV A,R7
MOV R4,A
MOV A,R5
MOV R2,A
MOV C,1EH
MOV 1FH,C
AS2: RET
EQ1: MOV A,R2 ;對階,比較兩個操作數的階碼
XRL A,R5
JZ AS4 ;階碼相同,對階結束
JB ACC.7,EQ3;階符互異
MOV A,R2 ;階符相同,比較大小
CLR C
SUBB A,R5
JC EQ4
EQ2: CLR C ;第二操作數右規壹次
MOV A,R6 ;尾數縮小壹半
RRC A
MOV R6,A
MOV A,R7
RRC A
MOV R7,A
INC R5 ;階碼加壹
ORL A,R6 ;尾數為零否?
JNZ EQ1 ;尾數不為零,繼續對階
MOV A,R2 ;尾數為零,提前結束對階
MOV R5,A
SJMP AS4
EQ3: MOV A,R2 ;判斷第壹操作數階符
JNB ACC.7,EQ2;如為正,右規第二操作數
EQ4: CLR C
LCALL RR1 ;第壹操作數右規壹次
ORL A,R3 ;尾數為零否?
JNZ EQ1 ;不為零,繼續對階
MOV A,R5 ;尾數為零,提前結束對階
MOV R2,A
AS4: JB F0,AS5 ;尾數加減判斷
MOV A,R4 ;尾數相加
ADD A,R7
MOV R4,A
MOV A,R3
ADDC A,R6
MOV R3,A
JNC AS2
LJMP RR1 ;有進位,右規壹次
AS5: CLR C ;比較絕對值大小
MOV A,R4
SUBB A,R7
MOV B,A
MOV A,R3
SUBB A,R6
JC AS6
MOV R4,B ;第壹尾數減第二尾數
MOV R3,A
LJMP RLN ;結果規格化
AS6: CPL 1FH ;結果的符號與第壹操作數相反
CLR C ;結果的絕對值為第二尾數減第壹尾數
MOV A,R7
SUBB A,R4
MOV R4,A
MOV A,R6
SUBB A,R3
MOV R3,A
RLN: MOV A,R3 ;浮點數規格化
ORL A,R4 ;尾數為零否?
JNZ RLN1
MOV R2,#0C1H;階碼取最小值
RET
RLN1: MOV A,R3
JB ACC.7,RLN2;尾數最高位為壹否?
CLR C ;不為壹,左規壹次
LCALL RL1
SJMP RLN ;繼續判斷
RLN2: CLR OV ;規格化結束
RET
RL1: MOV A,R4 ;第壹操作數左規壹次
RLC A ;尾數擴大壹倍
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2 ;階碼減壹
CJNE R2,#0C0H,RL1E;階碼下溢否?
CLR A
MOV R3,A ;階碼下溢,操作數以零計
MOV R4,A
MOV R2,#0C1H
RL1E: CLR OV
RET
RR1: MOV A,R3 ;第壹操作數右規壹次
RRC A ;尾數縮小壹半
MOV R3,A
MOV A,R4
RRC A
MOV R4,A
INC R2 ;階碼加壹
CLR OV ;清溢出標誌
CJNE R2,#40H,RR1E;階碼上溢否?
MOV R2,#3FH ;階碼溢出
SETB OV
RR1E: RET
(4) 標號:FMUL 功能:浮點數乘法
入口條件:被乘數在[R0]中,乘數在[R1]中?
出口信息:OV=0時,積仍在[R0]中,OV=1時,溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求:6字節
FMUL: LCALL MVR0 ;將[R0]傳送到第壹工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存積的符號
LCALL MUL0 ;計算積的絕對值
LJMP MOV0 ;將結果傳回到[R0]中
MUL0: LCALL MVR1 ;將[R1]傳送到第二工作區中
MUL1: MOV A,R3 ;第壹尾數為零否?
ORL A,R4
JZ MUL6
MOV A,R6 ;第二尾數為零否?
ORL A,R7
JZ MUL5
MOV A,R7 ;計算R3R4×R6R7-→R3R4
MOV B,R4
MUL AB
MOV A,B
XCH A,R7
MOV B,R3
MUL AB
ADD A,R7
MOV R7,A
CLR A
ADDC A,B
XCH A,R4
MOV B,R6
MUL AB
ADD A,R7
MOV R7,A
MOV A,B
ADDC A,R4
MOV R4,A
CLR A
RLC A
XCH A,R3
MOV B,R6
MUL AB
ADD A,R4
MOV R4,A
MOV A,B
ADDC A,R3
MOV R3,A
JB ACC.7,MUL2;積為規格化數否?
MOV A,R7 ;左規壹次
RLC A
MOV R7,A
LCALL RL1
MUL2: MOV A,R7
JNB ACC.7,MUL3
INC R4
MOV A,R4
JNZ MUL3
INC R3
MOV A,R3
JNZ MUL3
MOV R3,#80H
INC R2
MUL3: MOV A,R2 ;求積的階碼
ADD A,R5
MD: MOV R2,A ;階碼溢出判斷
JB ACC.7,MUL4
JNB ACC.6,MUL6
MOV R2,#3FH ;階碼上溢,設立標誌
SETB OV
RET
MUL4: JB ACC.6,MUL6
MUL5: CLR A ;結果清零(因子為零或階碼下溢)
MOV R3,A
MOV R4,A
MOV R2,#41H
MUL6: CLR OV
RET
(5) 標號: FDIV 功能:浮點數除法
入口條件:被除數在[R0]中,除數在[R1]中?
出口信息:OV=0時,商仍在[R0]中,OV=1時,溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求: 5字節
FDIV: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ DIV1
MOV @R0,#41H;被除數為零,不必運算
CLR OV
RET
DIV1: INC R1
MOV A,@R1
INC R1
ORL A,@R1
DEC R1
DEC R1
JNZ DIV2
SETB OV ;除數為零,溢出
RET
DIV2: LCALL MVR0 ;將[R0]傳送到第壹工作區中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數的符號
RLC A
MOV 1FH,C ;保存結果的符號
LCALL MVR1 ;將[R1]傳送到第二工作區中
LCALL DIV3 ;調用工作區浮點除法
LJMP MOV0 ;回傳結果
DIV3: CLR C ;比較尾數的大小
MOV A,R4
SUBB A,R7
MOV A,R3
SUBB A,R6
JC DIV4
LCALL RR1 ;被除數右規壹次
SJMP DIV3
DIV4: CLR A ;借用R0R1R2作工作寄存器
XCH A,R0 ;清零並保護之
PUSH ACC
CLR A
XCH A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV B,#10H ;除法運算,R3R4/R6R7-→R0R1
DIV5: CLR C
MOV A,R1
RLC A
MOV R1,A
MOV A,R0
RLC A
MOV R0,A
MOV A,R4
RLC A
MOV R4,A
XCH A,R3
RLC A
XCH A,R3
MOV F0,C
CLR C
SUBB A,R7
MOV R2,A
MOV A,R3
SUBB A,R6
ANL C,/F0
JC DIV6
MOV R3,A
MOV A,R2
MOV R4,A
INC R1
DIV6: DJNZ B,DIV5
MOV A,R6 ;四舍五入
CLR C
RRC A
SUBB A,R3
CLR A
ADDC A,R1 ;將結果存回R3R4
MOV R4,A
CLR A
ADDC A,R0
MOV R3,A
POP ACC ;恢復R0R1R2
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
MOV A,R2 ;計算商的階碼
CLR C
SUBB A,R5
LCALL MD ;階碼檢驗
LJMP RLN ;規格化
(6) 標號: FCLR 功能:浮點數清零
入口條件:操作數在[R0]中?
出口信息:操作數被清零?
影響資源:A 堆棧需求: 2字節
FCLR: INC R0
INC R0
CLR A
MOV @R0,A
DEC R0
MOV @R0,A
DEC R0
MOV @R0,#41H
RET
(7) 標號: FZER 功能:浮點數判零
入口條件:操作數在[R0]中?
出口信息:若累加器A為零,則操作數[R0]為零,否則不為零?
影響資源:A 堆棧需求: 2字節
FZER: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ ZERO
MOV @R0,#41H
ZERO: RET
(8) 標號: FMOV 功能:浮點數傳送
入口條件:源操作數在[R1]中,目標地址為[R0]?
出口信息:[R0]=[R1],[R1]不變?
影響資源:A 堆棧需求: 2字節
FMOV: INC R0
INC R0
INC R1
INC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
RET
(9) 標號: FPUS 功能:浮點數壓棧
入口條件:操作數在[R0]中?
出口信息:操作數壓入棧頂?
影響資源:A?R2?R3 堆棧需求: 5字節
FPUS: POP ACC ;將返回地址保存在R2R3中
MOV R2,A
POP ACC
MOV R3,A
MOV A,@R0 ;將操作數壓入堆棧
PUSH ACC
INC R0
MOV A,@R0
PUSH ACC
INC R0
MOV A,@R0
PUSH ACC
DEC R0
DEC R0
MOV A,R3 ;將返回地址壓入堆棧
PUSH ACC
MOV A,R2
PUSH ACC
RET ;返回主程序
(10) 標號: FPOP 功能:浮點數出棧
入口條件:操作數處於棧頂?
出口信息:操作數彈至[R0]中?
影響資源:A?R2?R3 堆棧需求: 2字節
FPOP: POP ACC ;將返回地址保存在R2R3中
MOV R2,A
POP ACC
MOV R3,A
INC R0
INC R0
POP ACC ;將操作數彈出堆棧,傳送到[R0]中
MOV @R0,A
DEC R0
POP ACC
MOV @R0,A
DEC R0
POP ACC
MOV @R0,A
MOV A,R3 ;將返回地址壓入堆棧
PUSH ACC
MOV A,R2
PUSH ACC
RET ;返回主程序
(11) 標號: FCMP 功能:浮點數代數值比較(不影響待比較操作數)
入口條件:待比較操作數分別在[R0]和[R1]中?
出口信息:若CY=1,則[R0] < [R1],若CY=0且A=0則 [R0] = [R1],否則[R0] > [R1]?
影響資源:A?B?PSW 堆棧需求: 2字節
FCMP: MOV A,@R0 ;數符比較
XRL A,@R1
JNB ACC.7,CMP2
MOV A,@R0 ;兩數異號,以[R0]數符為準
RLC A
MOV A,#0FFH
RET
CMP2: MOV A,@R1 ;兩數同號,準備比較階碼
MOV C,ACC.6
MOV ACC.7,C
MOV B,A
MOV A,@R0
MOV C,ACC.7
MOV F0,C ;保存[R0]的數符
MOV C,ACC.6
MOV ACC.7,C
CLR C ;比較階碼
SUBB A,B
JZ CMP6
RLC A ;取階碼之差的符號
JNB F0,CMP5
CPL C ;[R0]為負時,結果取反
CMP5: MOV A,#0FFH ;兩數不相等
RET
CMP6: INC R0 ;階碼相同時,準備比較尾數
INC R0
INC R1
INC R1
CLR C
MOV A,@R0
SUBB A,@R1
MOV B,A ;保存部分差
DEC R0
DEC R1
MOV A,@R0
SUBB A,@R1
DEC R0
DEC R1
ORL A,B ;生成是否相等信息
JZ CMP7
JNB F0,CMP7
CPL C ;[R0]為負時,結果取反
CMP7: RET
(12) 標號: FABS 功能:浮點絕對值函數
入口條件:操作數在[R0]中?
出口信息:結果仍在[R0]中?
影響資源:A 堆棧需求: 2字節
FABS: MOV A,@R0 ;讀取操作數的階碼
CLR ACC.7 ;清除數符
MOV @R0,A ;回傳階碼
RET
(13) 標號: FSGN 功能:浮點符號函數
入口條件:操作數在[R0]中?
出口信息:累加器 A=1 時為正數,A=0FFH時為負數,A=0 時為零?
影響資源:PSW?A 堆棧需求: 2字節
FSGN: INC R0 ;讀尾數
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ SGN
RET ;尾數為零,結束
SGN: MOV A,@R0 ;讀取操作數的階碼
RLC A ;取數符
MOV A,#1 ;按正數初始化
JNC SGN1 ;是正數,結束
MOV A,#0FFH ;是負數,改變標誌
SGN1: RET
(14) 標號: FINT 功能:浮點取整函數
入口條件:操作數在[R0]中?
出口信息:結果仍在[R0]中?
影響資源:PSW?A?R2?R3?R4?位1FH 堆棧需求: 6字節
FINT: LCALL MVR0 ;將[R0]傳送到第壹工作區中
LCALL INT ;在工作寄存器中完成取整運算
LJMP MOV0 ;將結果傳回到[R0]中
INT: MOV A,R3
ORL A,R4
JNZ INTA
CLR 1FH ;尾數為零,階碼也清零,結束取整
MOV R2,#41H
RET
INTA: MOV A,R2
JZ INTB ;階碼為零否?
JB ACC.7,INTB;階符為負否?
CLR C
SUBB A,#10H ;階碼小於16否?
JC INTD
RET ;階碼大於16,已經是整數
INTB: CLR A ;絕對值小於壹,取整後正數為零,負數為負壹
MOV R4,A
MOV C,1FH
RRC A
MOV R3,A
RL A
MOV R2,A
JNZ INTC
MOV R2,#41H
INTC: RET
INTD: CLR F0 ;舍尾標誌初始化
INTE: CLR C
LCALL RR1 ;右規壹次
ORL C,F0 ;記憶舍尾情況
MOV F0,C
CJNE R2,#10H,INTE;階碼達到16(尾數完全為整數)否?
JNB F0,INTF ;舍去部分為零否?
JNB 1FH,INTF;操作數為正數否?
INC R4 ;對於帶小數的負數,向下取整
MOV A,R4
JNZ INTF
INC R3
INTF: LJMP RLN ;將結果規格化
(15) 標號: FRCP 功能:浮點倒數函數
入口條件:操作數在[R0]中?
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求: 5字節
FRCP: MOV A,@R0
MOV C,ACC.7
MOV 1FH,C ;保存數符
MOV C,ACC.6 ;絕對值傳送到第二工作區
MOV ACC.7,C
MOV R5,A
INC R0
MOV A,@R0
MOV R6,A
INC R0
MOV A,@R0
MOV R7,A
DEC R0
DEC R0
ORL A,R6
JNZ RCP
SETB OV ;零不能求倒數,設立溢出標誌
RET
RCP: MOV A,R6
JB ACC.7,RCP2;操作數格式化否?
CLR C ;格式化之
MOV A,R7
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
DEC R5
SJMP RCP
RCP2: MOV R2,#1 ;將數值1.00傳送到第壹工作區
MOV R3,#80H
MOV R4,#0
LCALL DIV3 ;調用工作區浮點除法,求得倒數
LJMP MOV0 ;回傳結果
(16) 標號: FSQU 功能:浮點數平方
入口條件:操作數在[R0]中?
出口信息:OV=0時,平方值仍然在[R0]中,OV=1時溢出?
影響資源:PSW?A?B?R2~R7?位1EH?1FH 堆棧需求: 9字節
FSQU: MOV A,R0 ;將操作數
XCH A,R1 ;同時作為乘數
PUSH ACC ;保存R1指針
LCALL FMUL ;進行乘法運算
POP ACC
MOV R1,A ;恢復R1指針
RET
(17) 標號: FSQR 功能:浮點數開平方(快速逼近算法)
入口條件:操作數在[R0]中?
出口信息:OV=0時,平方根仍在[R0]中,OV=1時,負數開平方出錯?
影響資源:PSW?A?B?R2~R7 堆棧需求: 2字節
FSQR: MOV A,@R0
JNB ACC.7,SQR
SETB OV ;負數開平方,出錯
RET
SQR: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ SQ
MOV @R0,#41H;尾數為零,不必運算
CLR OV
RET
SQ: MOV A,@R0
MOV C,ACC.6 ;將階碼擴展成8bit補碼
MOV ACC.7,C
INC A ;加壹
CLR C
RRC A ;除二
MOV @R0,A ;得到平方根的階碼,回存之
INC R0 ;指向被開方數尾數的高字節
JC SQR0 ;原被開方數的階碼是奇數嗎?
MOV A,@R0 ;是奇數,尾數右規壹次
RRC A
MOV @R0,A
INC R0
MOV A,@R0
RRC A
MOV @R0,A
DEC R0
SQR0: MOV A,@R0
JZ SQR9 ;尾數為零,不必運算
MOV R2,A ;將尾數傳送到R2R3中
INC R0
MOV A,@R0
MOV R3,A
MOV A,R2 ;快速開方,參閱定點子程序說明
ADD A,#57H
JC SQR2
ADD A,#45H
JC SQR1
ADD A,#24H
MOV B,#0E3H
MOV R4,#80H
SJMP SQR3
SQR1: MOV B,#0B2H
MOV R4,#0A0H
SJMP SQR3
SQR2: MOV B,#8DH
MOV R4,#0D0H
SQR3: MUL AB
MOV A,B
ADD A,R4
MOV R4,A
MOV B,A
MUL AB
XCH A,R3
CLR C
SUBB A,R3
MOV R3,A
MOV A,B
XCH A,R2
SUBB A,R2
MOV R2,A
SQR4: SETB C
MOV A,R4
RLC A
MOV R6,A
CLR A
RLC A
MOV R5,A
MOV A,R3
SUBB A,R6
MOV B,A
MOV A,R2
SUBB A,R5
JC SQR5
INC R4
MOV R2,A
MOV R3,B
SJMP SQR4
SQR5: MOV A,R4
XCH A,R2
RRC A
MOV F0,C
MOV A,R3
MOV R5,A
MOV R4,#8
SQR6: CLR C
MOV A,R3
RLC A
MOV R3,A
CLR C
MOV A,R5
SUBB A,R2
JB F0,SQR7
JC SQR8
SQR7: MOV R5,A
INC R3
SQR8: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV F0,C
DJNZ R4,SQR6
MOV A,R3 ;將平方根的尾數回傳到[R0]中
MOV @R0,A
DEC R0
MOV A,R2
MOV @R0,A
SQR9: DEC R0 ;數據指針回歸原位
CLR OV ;開方結果有效
RET
(18) 標號: FPLN 功能:浮點數多項式計算
入口條件:自變量在[R0]中,多項式系數在調用指令之後,以40H結束?
出口信息:OV=0時,結果仍在[R0]中,OV=1時,溢出?
影響資源:DPTR?PSW?A?B?R2~R7?位1EH?1FH 堆棧需求: 4字節
FPLN: POP DPH ;取出多項式系數存放地址
POP DPL
XCH A,R0 ;R0?R1交換角色,自變量在[R1]中
XCH A,R1
XCH A,R0
CLR A ;清第壹工作區
MOV R2,A
MOV R3,A
MOV R4,A
CLR 1FH
PLN1: CLR A ;讀取壹個系數,並裝入第二工作區
MOVC A,@A+DPTR
MOV C,ACC.7
MOV 1EH,C
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R6,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R7,A
INC DPTR ;指向下壹個系數
MOV C,1EH ;比較兩個數符
RRC A
XRL A,23H
RLC A
MOV F0,C ;保存比較結果
LCALL AS1 ;進行代數加法運算
CLR A ;讀取下壹個系數的第壹個字節
MOVC A,@A+DPTR
CJNE A,#40H,PLN2;是結束標誌嗎?
XCH A,R0 ;運算結束,恢復R0?R1原來的角色
XCH A,R1
XCH A,R0
LCALL MOV0 ;將結果回傳到[R0]中
CLR A
INC DPTR
JMP @A+DPTR ;返回主程序
PLN2: MOV A,@R1 ;比較自變量和中間結果的符號
XRL A,23H
RLC A
MOV 1FH,C ;保存比較結果
LCALL MUL0 ;進行乘法運算
SJMP PLN1 ;繼續下壹項運算
(19) 標號: FLOG 功能:以10為底的浮點對數函數
入口條件:操作數在[R0]中?
出口信息:OV=0時,結果仍在[R0]中,OV=1時,負數或零求對數出錯?
影響資源:DPTR?PSW?A?B?R2~R7?位1EH?1FH 堆棧需求:9字節
FLOG: LCALL FLN ;先以e為底求對數
JNB OV,LOG
RET ;如溢出則停止計算
LOG: MOV R5,#0FFH;系數0.43430(1/Ln10)
MOV R6,#0DEH
MOV R7,#5CH
LCALL MUL1 ;通過相乘來換底
LJMP MOV0 ;傳回結果