;**** WRITER:COCO.LI *************
; 定時器T0、T1溢出周期為50MS（10MS），T0為秒計數用，T1為調整時閃爍用，
;**** P1.0、P1.1、P1.2為調整按鈕，P0口為字符輸出口，采用***陽顯示管。
;********** 中斷程序入口 ****************
ORG 0000H ;程序執行開始地址
LJMP START ;跳到標號START執行
ORG 0003H ;外中斷0中斷程序入口
RETI ;外中斷0中斷返回
ORG 000BH ;定時器T0中斷程序入口
LJMP INTT0 ;跳到標號INTT0執行
ORG 0013H ;外中斷1中斷程序入口
RETI ;外中斷1中斷返回
ORG 001BH ;定時器T1中斷程序入口
LJMP INTT1 ;跳到標號INTT1執行
ORG 0023H ;串行口中斷程序入口
RETI ;串行口中斷程序返回
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 主程序 ;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
ORG 0030H ;
START:LCALL ST ;上電顯示年月日及班級學號
MOV R0,#70H ;清70H~7AH***11個內存單元
MOV R7,#0BH ;
CLEARDISP:
MOV @R0,#00H
INC R0
DJNZ R7,CLEARDISP
MOV 20H,#00H ;清20H , 標誌用
MOV 7AH,#0AH ;放入“熄滅符”數據
MOV TMOD,#11H ;設T0、T1為16位定時器
MOV TL0,#0B0H ;50MS定時初值，T0計時用
MOV TH0,#3CH ;50MS定時初值
MOV TL1,#0B0H ;50MS定時初值，T1閃爍定時用
MOV TH1,#3CH ;50MS定時初值
SETB EA ;總中斷開放
SETB ET0 ;允許T0中斷
SETB TR0 ;開啟T0定時器
MOV R4,#14H ;1 S定時用初值50MS*20
START1:
LCALL DISPLAY ;調用顯示子程序
JNB P3.3,SETMM1 ;P3.3口為0時,轉時間調整程序
JNB P3.4,FUNSS ;秒表功能,P3.4按鍵調時時作減1操作
JNB P3.5,FUNPT ;STOP,PUSE,CLR
SJMP START1 ;P3.3口為1時跳回START1
SETMM1:
LJMP SETMM ;轉到時間調整程序SETMM
FUNSS:
LCALL DS20MS ;
JB P3.4,START1 ;
WAIT11: ;
JNB P3.4,WAIT11 ;
CPL 03H ;
MOV 70H,#00H ;
MOV 70H,#00H ;
MOV 70H,#00H
MOV 70H,#00H ;
MOV 70H,#00H ;
MOV 70H,#00H ;
AJMP START1 ;
FUNPT: ;
LCALL DS20MS ;
JB P3.5,START1 ;
WAIT22: ;
JNB P3.5,WAIT21 ;
CLR ET0 ;
CLR TR0 ;
WAIT33: ;
JB P3.5,WAIT31 ;
LCALL DS20MS ;
JB P3.5,WAIT33 ;
WAIT66:
JNB P3.5,WAIT61
MOV R0,#70H ;清70H~79H***10個內存單元
MOV R7,#0AH
CLEARP:
MOV @R0,#00H
INC R0
DJNZ R7,CLEARP
WAIT44:
JB P3.5,WAIT41
LCALL DS20MS
JB P3.5,WAIT44
WAIT55:
JNB P3.5,WAIT51
SETB ET0
SETB TR0
AJMP START1
WAIT21:
LCALL DISPLAY
AJMP WAIT22
WAIT31:
LCALL DISPLAY
AJMP WAIT33
WAIT41:
LCALL DISPLAY
AJMP WAIT44
WAIT51:
LCALL DISPLAY
AJMP WAIT55
WAIT61:
LCALL DISPLAY
AJMP WAIT66
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;; 1 s計時程式 ;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; T0中斷服務程序
INTT0:
PUSH ACC ;累加器入棧保護
PUSH PSW ;狀態字入棧保護
CLR ET0 ;關T0中斷允許
CLR TR0 ;關定時器T0
JB 03H,FSS ;標誌為1轉秒表處理程序,,10MS定時
MOV A,#0B7H ;中斷響應時間同步修正
ADD A,TL0 ;低8位初值修正
MOV TL0,A ;重裝初值,,低8位修正值
MOV A,#3CH ;高8位初值修正
ADDC A,TH0
MOV TH0,A ;重裝初值,, 高8位修正值
SETB TR0 ;開啟定時器T0
DJNZ R4,OUTT0;20次中斷未到中斷退出
ADDSS:
MOV R4,#14H ;20次中斷到,重賦初值,,1S
MOV R0,#71H ;指向秒計時單元..71H~72H
ACALL ADD1 ;調用加1程序,,加1S操作.
MOV A,R3 ;秒數據放入A,,R3為2位十進制數組合
CLR C ;清進位標誌
CJNE A,#60H,ADDMM
ADDMM:
JC OUTT0 ;短於60S時中斷退出
ACALL CLR0 ;長於或者等於60S時對秒計數單元清0
MOV R0,#77H ;指向分計時單元,,76H~77H
ACALL ADD1 ;分計時單元加1
MOV A,R3 ;分數據放入A
CLR C ;清進位標誌
CJNE A,#60H,ADDHH ;秒表時最大為99
ADDHH:
JC OUTT0 ;短於60min時中斷退出
ACALL CLR0 ;長於或者等於60min時對分計數單元清0
MOV R0,#79H ;指向分計時單元,,78H~79H
ACALL ADD1 ;小時計時單元加1h
MOV A,R3 ;時數據放入A
CLR C ;清進位標誌
JB 03H,OUTT0 ;秒表時最大為99
CJNE A,#24H,HOUR
HOUR:
JC OUTT0 ;短於24h時中斷退出
ACALL CLR0 ;長於或者等於24h時對計時單元清0
OUTT0:
MOV 72H,76H ;中斷退出時將分\時計時單元數據移
MOV 73H,77H ;入對應顯示單元
MOV 74H,78H
MOV 75H,79H
POP PSW ;恢復狀態字出棧
POP ACC ;恢復累加器
SETB ET0 ;開放T0中斷
RETI
;秒表計時程序（10min加1），低2位為0.1、0.01秒,中間2位為秒,最高2位為分.
;最大計數值為99分59.99秒
FSS: MOV A,#0F7H
ADD A,TL0
MOV TL0,A
MOV A,#0D8H
ADDC A,TH0
MOV TH0,A
SETB TR0
MOV R0,#71H
ACALL ADD1
CLR C
MOV A,R3
JZ FSS1
SETB C
FSS1: AJMP ADDMM
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 閃動調時程式 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; T1中斷服務程序,用作時間調整單元閃爍指示
INTT1: PUSH ACC
PUSH PSW
MOV TL1,#0B0H
MOV TH1,#3CH
DJNZ R2,INTT1OUT
MOV R2,#06H
CPL 02H
JB 02H,FLASH1
MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
INTT1OUT:
POP PSW
POP ACC
RETI
FLASH1: JB 01H,FLASH2
MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
FLASH2: MOV 72H,76H
MOV 73H,77H
MOV 74H,78H
MOV 75H,79H
AJMP INTT1OUT
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
ADD1: MOV A,@R0 ;取當前計時單元數據到A
DEC R0 ;指向前壹地址
SWAP A ;A中數據高四位與低四位交換
ORL A,@R0 ;前壹地址中數據放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十進制調整
MOV R3,A ;移入R3中暫存數據
ANL A,#0FH ;高四位變0
MOV @R0,A ;數據放入當前地址單元中
MOV A,R3 ;返回
INC R0
SWAP A
ANL A,#0FH
MOV @R0,A
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 分減1子程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
SUB1: MOV A,@R0 ;取當前計時單元數據到A
DEC R0 ;指向前壹地址
SWAP A ;A中數據高四位與低四位交換
ORL A,@R0 ;前壹地址中數據放入A中低四位
JZ SUB11
DEC A ;A減1操作
SUB111: MOV R3,A ;移入R3中暫存數據
ANL A,#0FH ;高四位變0
CLR C ;清進位標誌
SUBB A,#0AH
SUB1111:
JC SUB1110
MOV @R0,#09H ;大於等於0AH,為9
SUB110:
MOV A,R3 ;取回R3中暫存數據
INC R0 ;指向當前地址單元
SWAP A ;A中數據高四位與低四位交換
ANL A,#0FH ;高四位變0
MOV @R0,A ;數據放入當前地址單元中
RET ;返回
SUB11: MOV A,#59H
AJMP SUB111
SUB1110:
MOV A,R3 ;移入R3寄存器
ANL A,#0FH
MOV @R0,A
AJMP SUB110
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 時減1子程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
SUBB1: MOV A,@R0 ;取當前計時單元數據到A
DEC R0 ;指向前壹地址
SWAP A ;A中數據高四位與低四位交換
ORL A,@R0 ;前壹地址中數據放入A中低四位
JZ SUBB11 ;00減1為23H
DEC A ;A減1操作
SUBB111:MOV R3,A ;;移入R3中暫存數據
ANL A,#0FH ;高四位變0
CLR C ;清進位標誌
SUBB A,#0AH ;時個位大於9為9
SUBB1111:
JC SUBB1110
MOV @R0,#09H ;大於等於0AH,為9
SUBB110:
MOV A,R3 ;取回R3中暫存數據
INC R0 ;指向當前地址單元
SWAP A ;A中數據高四位與低四位交換
ANL A,#0FH ;高四位變0
MOV @R0,A ;數據放入當前地址單元中
RET ;返回
SUBB11:
MOV A,#23H
AJMP SUBB111
SUBB1110:
MOV A,R3 ;時個位小於0A不處理
ANL A,#0FH ;高四位變0
MOV @R0,A ;個位移入
AJMP SUBB110
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清0程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;對計時單元復0用
CLR0: CLR A ;清累加器
MOV @R0,A ;清當前地址單元
DEC R0 ;指向前壹地址
MOV @R0,A ;前壹地址單元清0
RET ;子程序返回
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 時鐘調整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;當調時按鍵按下時進入此程序
SETMM: CLR ET0 ;關定時器T0中斷
CLR TR0 ;關閉定時器T0
LCALL DL1S ;調用1S延時程序
JB P3.3,CLOSEDIS ;鍵按下時間短於1S,關閉顯示,,省電
MOV R2,#06H ;進入調時狀態,賦閃爍定時初值
SETB ET1 ;允許T1中斷
SETB TR1 ;開啟T1定時器
SET2:
JNB P3.3,SET1 ;P3.3口為0時,等待,,鍵未釋放
SETB 00H ;鍵釋放,分調整閃爍標誌置1
SET4: ;等待鍵按下
JB P3.3,SET3 ;等待鍵按下
LCALL DL05S ;有鍵按下,延時0.5S
JNB P3.3,SETHH ;按下時間長於0.5S,轉調小時狀態
MOV R0,#77H ;按下時間短於0.5S,加1min操作
LCALL ADD1 ;調用加1子程序
MOV A,R3 ;取調整單元數據
CLR C ;消位標誌
CJNE A,#60H,HHH ;調整單元數據與60比較
HHH: JC SET4 ;調整單元數據小於60,轉SET4循環
LCALL CLR0 ;調整單元數據大於或等於60時,清0
CLR C ;清進位0
AJMP SET4 ;跳轉到SET4循環
CLOSEDIS:
SETB ET0 ;省電狀態,開T0中斷,,LED燈不顯示
SETB TR0 ;開啟T0中斷
CLOSE:
JB P3.3,CLOSE ;無鍵按下,等待
LCALL DISPLAY ;有鍵按下,調用顯示子程序延時消抖
JB P3.3,CLOSE ;是幹擾,返回CLOSE等待
WAITH:
JNB P3.3,WAITH ;等待鍵釋放
LJMP START1 ;返回主程序,,LED數據顯示亮
SETHH: CLR 00H ;分閃爍標誌清除,,進入調小時狀態
SETHH1: JNB P3.3,SET5 ;等待鍵釋放
SETB 01H ;小時調整標誌置1
SET6: JB P3.3,SET7 ;等待鍵按下
LCALL DL05S ;有鍵按下,延時0.5S
JNB P3.3,SETOUT ;按下時間長於0.5S,退出時間調整
MOV R0,#79H ;按下時間短於0.5S,加1h操作
LCALL ADD1 ;調用加1子程序
MOV A,R3
CLR C
CJNE A,#24H,HOUU ;計時單元數據與24比較
HOUU: JC SET6 ;小於24,轉SET6循環
LCALL CLR0 ;大於或等於24時,清0操作
AJMP SET6 ;跳到SET6處循環
SETOUT: JNB P3.3,SETOUT1 ;調時退出程序.等待鍵釋放
LCALL DISPLAY ;延時消抖
JNB P3.3,SETOUT ;是抖動,返回SETOUT再等待
CLR 01H ;清調小時標誌
CLR 00H ;清調分標誌
CLR 02H ;清閃爍標誌
CLR TR1 ;關閉定時器T1
CLR ET1 ;關定時器T1中斷
SETB TR0 ;開啟定時器T0
SETB ET0 ;開啟定時器T0中斷,,計時開始
LJMP START1 ;跳回主程序
SET1: LCALL DISPLAY ;鍵釋放等待調時用顯示程序
AJMP SET2 ;防止鍵按下時無時鐘顯示
SET3: LCALL DISPLAY ;等待調分按鍵時時鐘顯示用
JNB P3.3,FUNSUB ;減1分操作
AJMP SET4 ;調分等待
SET5: LCALL DISPLAY ;鍵釋放等待調時用顯示程序
AJMP SETHH1 ;防止鍵按下時無時鐘顯示
SET7: LCALL DISPLAY ;等待調小時按鍵時時鐘顯示用
JNB P3.3,FUNSUBB ;小時減1操作
AJMP SET6 ;調時等待
SETOUT1:LCALL DISPLAY ;退出時鐘整時鍵釋放等待
AJMP SETOUT ;防止鍵按下時無時鐘顯示
;FUNSUB,分減1程序？
FUNSUB: LCALL DISPLAY ;延時消抖
JB P3.3,SET41 ;幹擾,返回調分等待
FUNSUB1:JNB P3.3,FUNSUB1 ;等待鍵放開
MOV R0,#77H
LCALL SUB1 ;分減1程序
LJMP SET4 ;返回調分等待
SET41: LJMP SET4
;FUNSUB,時減1程序？
FUNSUBB:LCALL DISPLAY ;消抖動
JB P3.4,SET61 ;幹擾，返回調時等待
FUNSUBB1:JNB P3.4,FUNSUBB1
MOV R0,#79H
LCALL SUBB1
LJMP SET6
SET61: LJMP SET6
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 顯示程序 ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;顯示數據在70H~75H單元內，用六位LED***陽數碼管顯示。
;掃描控制，每個LED數碼管亮1mS時間。
DISPLAY:
MOV R1,#70H ;指向顯示數據首址
MOV R5,#0DFH ;掃描控制字初值
PLAY: MOV A,R5 ;掃描字放入A
MOV P2,A ;從P2口輸出
MOV A,@R1 ;取顯示數據到A
MOV DPTR,#TAB ;取段碼表地址
MOVC A,@A+DPTR ;查顯示數據對應段碼
MOV P0,A ;段碼放入P0口
MOV A,R5
JB ACC_1,LOOP5 ;小數點處理
CLR P0.7
LOOP5: JB ACC_3,LOOP6
CLR P0.7
LOOP6: LCALL DL1MS ;顯示1MS
INC R1 ;指向下壹地址
MOV A,R5 ;掃描控制字放入A
JNB ACC_0,ENDOUT ;ACC.0=0時,壹次顯示結束
RR A ;A中數據循環左移
MOV R5,A ;放回R5內
MOV P0,#0FFH
AJMP PLAY ;跳回:PLAY循環.
ENDOUT: MOV P2,#0FFH ;壹次顯示結束,P2口復位
MOV P0,#0FFH ;P0口復位
RET ;子程序返回
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH,88H,0BFH
;***陽段碼表 1、 2、 3、 4、 5、 6、 7、 8、 9、不亮、A、—。
;SDISPLAY,上電顯示程序
;不帶小數點，有A、— 顯示功能
SDISPLAY:
MOV R5,#0DFH ;掃描控制字初值
SPLAY: MOV A,R5 ;掃描字放入A
MOV P2,A ;從P2口輸出
MOV A,@R1 ;取顯示數據到A
MOV DPTR,#TABS ;取段碼表地址
MOVC A,@A+DPTR ;查顯示數據對應段碼
MOV P0,A ;段碼放入P0口
MOV A,R5
LCALL DL1MS ;顯示1MS
INC R1 ;指向下壹地址
MOV A,R5 ;掃描控制字放入A
JNB ACC_0,ENDOUTS ;ACC.0=0時,壹次顯示結束
RR A ;A中數據循環左移
MOV R5,A ;放回R5內
AJMP SPLAY ;跳回:PLAY循環.
ENDOUTS:MOV P2,#0FFH ;壹次顯示結束,P2口復位
MOV P0,#0FFH ;P0口復位
RET ;子程序返回
TABS: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH,88H,0BFH
;STAB表，啟動時顯示2003-12-07、A01-2-28
STAB: DB 0AH,0AH,0AH,0AH,0AH,0AH,08H,02H,0CH,02H,0CH,01H,00H,0BH,0AH,0AH
DB 07H,00H,0CH
DB 07H,00H,0CH,02H,01H,0CH,03H,00H,00H,02H,0AH,0AH,0AH,0AH,0AH,0AH
;註：0A不亮，0B顯示“A”，0C顯示“-”
;ST子程序，上電時顯示年月日用，采用移動顯示
ST: MOV R0,#40H ;將顯示內容移入40H~50H單元
MOV R2,#20H
MOV R3,#00H
CLR A
MOV DPTR,#STAB
SLOOP:
MOVC A,@A+DPTR
MOV @R0,A
MOV A,R3
INC A
MOV R3,A
INC R0
DJNZ R2,SLOOP ;移入完畢
MOV R1,#5AH
MOV R3,#1BH ;顯示27個單元
SSLOOP:
MOV R2,#32H ;控制移動速度
SSLOOP1:
LCALL SDISPLAY
DJNZ R2,SSLOOP11
MOV A,R1
SUBB A,#07H ;顯示首址修正為低1個單元
MOV R1,A
DJNZ R3,SSLOOP
RET
SSLOOP11:
MOV A,R1 ;指針修正為原值
SUBB A,#06H
MOV R1,A
AJMP SSLOOP1
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;; 延時程序 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;1ms延時程序，LED顯示程序用
DL1MS: MOV R6,#14H
DL1: MOV R7,#19H
DL2: DJNZ R7,DL2
DJNZ R6,DL1
RET;20MS延時程序，采用調用顯示子程序，以改善LED的顯示閃爍現象
DS20MS: ACALL DISPLAY
ACALL DISPLAY
ACALL DISPLAY
RET;延時程序，用作按鍵時間的長短判斷
DL1S:
LCALL DL05S
LCALL DL05S
RET
DL05S:
MOV R3,#20H ;8ms*32=0.196s
DL05S1:
LCALL DISPLAY
DJNZ R3,DL05S1
RET;
END ;程序結束