Word支持多種分節符，如圖壹，其中兩種分節符會在必要時自動插入空白頁。例如，如果文檔中插入了壹個“奇數頁”分節符，而上壹節又在奇數頁結束，則Word會自動插入壹個空白的偶數頁，使得下壹節又屬於壹個新的奇數頁。
但通過這兩種分節符自動插入的空白頁都存在同樣的缺點——它插入的是壹個完全空白的頁，連頁眉/頁腳都自作主張地省略了。在實際應用中，自動生成的空白頁如果也有普通擁有的頁眉/頁腳，或者包含“（本頁空白）”之類的文字，整個文檔看起來就更規範壹些。但這些問題單純依靠Word的分節符來自動插入空白頁是無法解決的。
圖壹
解決這個問題辦法很多。第壹種辦法最簡單，但比較繁瑣，屬於“笨辦法”，針對只需加入頁眉/頁腳的空白頁：人工檢視文檔，在必要的地方（也即空白頁）插入壹些不可見的文本。所謂不可見的文本，就是將普通文本的顏色設置成和底色壹樣，壹般是白色。這樣，打印時空白頁上不會看到這些文本，不過Word不會考慮到這壹點，仍會象對待正常頁那樣在這個“空白”頁上打印頁眉/頁腳。
如果要加入“（本頁空白）”之類的文字，壹種比較好的辦法是利用域構造標準的“節終結文本”。
首先創建壹個AutoText自動圖文集，使它包含要打印在空白頁上的文字，並在自動圖文集的開始位置插入壹個分頁符。為該自動圖文集詞條指定適當的名稱，例如BLANKPAGE。接下來，在每壹個節的終結處，緊靠分節符之前，加入下面的復合域（如圖二）：{ if { =int( {page} / 2 ) * 2 } = { page } " " { autotext "BLANKPAGE" } }。
這組域代碼判斷當前的頁號是奇數還是偶數，根據判斷結果決定是否插入名為BLANKPAGE的自動圖文集詞條。
註意域代碼中的花括號（“{”和“}”）是域的標記，不能用輸入普通文字的方法輸入，每壹對花括號必須按壹次Ctrl+F9輸入。
如果妳經常要執行類似的.操作，那麽最好的辦法還是利用Word宏。下面的CheckSecPages宏遍歷當前文檔，對於文檔的每壹節，計算該節包含的頁數，然後判斷頁數的奇偶性，必要時插入分頁符。
Sub CheckSecPages()
Dim iSec As Integer
Dim oRng As Range
Dim iValue As Integer
With ActiveDocument
' 依次處理文檔的每壹節（最後壹節除外）
For iSec = 1 To .Sections.Count - 1
' 創建區域（Range）對象
Set oRng = .Sections(iSec).Range
' 將該區域折疊
' （折疊之後起始位置和結束位置相同）
oRng.Collapse wdCollapseStart
' 插入壹個SectionPages域。
' SectionPages域表示壹節中的總頁數
.Fields.Add Range:=oRng, Type:=wdFieldSectionPages
' 將SectionPages的值除以2。如果余數為0，則當前節的頁數是
' 偶數——這就是我們要用“奇數頁”分節符達到的效果
If (.Sections(iSec).Range.Fields(1).Result Mod 2) <> 0 Then
' 如果頁數是奇數，則在節的分節符之前
' 插入壹個分頁符
Set oRng = .Sections(iSec).Range
With oRng
.Collapse Direction:=wdCollapseEnd
.MoveEnd unit:=wdCharacter, Count:=-1
.InsertBreak Type:=wdPageBreak
End With
End If
' 刪除前面創建的SectionPages域
.Sections(iSec).Range.Fields(1).Delete
Next iSec
End With
End Sub
在Word中，按Alt+F11打開Visual Basic宏編輯器，輸入CheckSecPages宏的完整代碼，如圖三。完成後保存，關閉宏編輯器返回Word。以後，只要運行CheckSecPages宏就可以自動設置空白頁，非常方便。