.常量 軟件標題, "“簡單瀏覽器”"
.常量 WM_SYSCOMMAND, "274"
.常量 SC_MAXIMIZE, "61488"
.版本 2
.支持庫 WebBrowser
.支持庫 iext3
.支持庫 iext
.程序集 窗口程序集1
.程序集變量 網頁框數組, WebBrowser, , "0"
.程序集變量 當前網頁框, WebBrowser
.程序集變量 當前子夾, 整數型
.子程序 __啟動窗口_創建完畢
_啟動窗口.標題 ＝ #軟件標題
_啟動窗口.發送信息 (#WM_SYSCOMMAND, #SC_MAXIMIZE, 0) ' 最大化窗口
高級選擇夾1.刪除子夾 (0)
_按鈕1_被單擊 ()
.子程序 __啟動窗口_尺寸被改變
.局部變量 i, 整數型
連續賦值 (取用戶區寬度 (), 工具條1.寬度, 工具條2.寬度, 高級選擇夾1.寬度)
WebBrowser1.移動 (0, 高級選擇夾1.頂邊 ＋ 高級選擇夾1.高度, 取用戶區寬度 (), 狀態條1.頂邊 － 高級選擇夾1.頂邊 － 高級選擇夾1.高度)
按鈕1.左邊 ＝ 取用戶區寬度 () － 按鈕1.寬度 － 8
編輯框1.寬度 ＝ 按鈕1.左邊 － 編輯框1.左邊 － 5
.計次循環首 (取數組成員數 (網頁框數組), i)
網頁框數組 [i].移動 (WebBrowser1.左邊, WebBrowser1.頂邊, WebBrowser1.寬度, WebBrowser1.高度)
.計次循環尾 ()
.子程序 _按鈕1_被單擊
.如果真 (刪首尾空 (編輯框1.內容) ≠ “”)
新建網頁 (刪首尾空 (編輯框1.內容))
.如果真結束
.子程序 新建網頁
.參數 網頁地址, 文本型
.局部變量 子夾索引, 整數型
.局部變量 i, 整數型
.計次循環首 (取數組成員數 (網頁框數組), i)
網頁框數組 [i].可視 ＝ 假
.計次循環尾 ()
復制窗口組件 (WebBrowser1, 當前網頁框)
加入成員 (網頁框數組, 當前網頁框)
當前網頁框.移動 (WebBrowser1.左邊, WebBrowser1.頂邊, WebBrowser1.寬度, WebBrowser1.高度)
當前網頁框.可視 ＝ 真
.如果 (高級選擇夾1.取子夾名稱 (0) ＝ “”)
當前子夾 ＝ 0
高級選擇夾1.置子夾名稱 (0, “load..”)
.否則
當前子夾 ＝ 高級選擇夾1.加入子夾 (“load..”, , , , )
高級選擇夾1.現行子夾 ＝ 當前子夾
.如果結束
.如果真 (網頁地址 ≠ “”)
當前網頁框.Navigate (網頁地址, , , , )
.如果真結束
.子程序 _高級選擇夾1_子夾被改變
.局部變量 i, 整數型
當前子夾 ＝ 高級選擇夾1.現行子夾
當前網頁框 ＝ 網頁框數組 [當前子夾 ＋ 1]
.計次循環首 (取數組成員數 (網頁框數組), i)
網頁框數組 [i].可視 ＝ 假
.計次循環尾 ()
當前網頁框.可視 ＝ 真
_啟動窗口.標題 ＝ 當前網頁框.GetDocument ().讀文本屬性 (“title”, )
.子程序 _高級選擇夾1_子夾頭被右擊
.參數 子夾索引, 整數型
.如果真 (子夾索引 ＝ 當前子夾)
當前網頁框.銷毀 ()
刪除成員 (網頁框數組, 當前子夾 ＋ 1, 1)
.如果 (高級選擇夾1.取子夾數目 () ＞ 1)
高級選擇夾1.刪除子夾 (當前子夾)
高級選擇夾1.現行子夾 ＝ 高級選擇夾1.取子夾數目 () － 1
_高級選擇夾1_子夾被改變 ()
.否則
高級選擇夾1.置子夾名稱 (0, “”)
新建網頁 (“about:blank”)
.如果結束
.如果真結束
.子程序 _WebBrowser1_StatusTextChange, , , 狀態文本被改變
.參數 Text, 文本型
.局部變量 事件組件, WebBrowser
事件組件 ＝ 取事件組件 ()
.如果真 (事件組件 ＝ 當前網頁框)
狀態條1.置文本 (0, Text)
.如果真結束
.子程序 _WebBrowser1_TitleChange, , , 標題被改變
.參數 Text, 文本型
.局部變量 事件組件, WebBrowser
.局部變量 i, 整數型
事件組件 ＝ 取事件組件 ()
.如果真 (事件組件 ＝ 當前網頁框)
_啟動窗口.標題 ＝ Text ＋ “ - ” ＋ #軟件標題
.如果真結束
.計次循環首 (取數組成員數 (網頁框數組), i)
.如果真 (網頁框數組 [i] ＝ 事件組件)
高級選擇夾1.置子夾名稱 (i － 1, 取文本左邊 (Text, 16))
高級選擇夾1.置子夾提示文本 (i － 1, Text)
.如果真結束
.計次循環尾 ()
.子程序 _WebBrowser1_NewWindow2, , , 彈出新窗口
.參數 ppDisp, 對象, 參考
.參數 Cancel, 邏輯型, 參考
新建網頁 (“”)
ppDisp ＝ 當前網頁框.GetApplication ()
.子程序 _WebBrowser1_DownloadComplete, , , 下載完畢
.局部變量 事件組件, WebBrowser
事件組件 ＝ 取事件組件 ()
.如果真 (事件組件 ＝ 當前網頁框)
編輯框1.內容 ＝ 事件組件.LocationURL ' 當前地址
.如果真結束
.子程序 _工具條1_被單擊
.參數 按鈕索引, 整數型
.判斷開始 (按鈕索引 ＝ 1)
當前網頁框.GoBack () ' 後退
.判斷 (按鈕索引 ＝ 2)
當前網頁框.GoForward () ' 前進
.判斷 (按鈕索引 ＝ 3)
當前網頁框.Stop () ' 停止
.判斷 (按鈕索引 ＝ 4)
當前網頁框.Refresh () ' 刷新
.默認
.判斷結束
.子程序 _編輯框1_按下某鍵, 邏輯型
.參數 鍵代碼, 整數型
.參數 功能鍵狀態, 整數型
.如果真 (鍵代碼 ＝ #回車鍵)
_按鈕1_被單擊 ()
.如果真結束
具體支持庫 請自己在官方論壇找