.程序集 窗口程序集1
.程序集變量 輸入的密碼, 文本型
.程序集變量 設置的密碼, 文本型
.程序集變量 第壹次運行, 邏輯型
.子程序 __啟動窗口_創建完畢
鎖鍵 (97, 1, 0, 0)
設置的密碼 ＝ 取文本註冊表項 (“SYSTEMSET”, “SET”, “PMM”, “”)
是否隱藏窗口 ＝ 取數值註冊表項 (“SYSTEMSET”, “SET”, “DESK”, 1)
.如果 (設置的密碼 ＝ “”)
第壹次運行 ＝ 真
總在最前 ＝ 假
解鎖按鈕.禁止 ＝ 真
退出按鈕.禁止 ＝ 假
設置按鈕.禁止 ＝ 假
設置按鈕.獲取焦點 ()
信息框 (“本程序還未進行設置，請按下設置鈕對本程序進行初始設置！”, #信息圖標, “信息：”)
.否則
.如果真 (是否隱藏窗口 ＝ 1)
位置 ＝ 3
.如果真結束
設置鼠標位置 ()
.如果結束
.子程序 _密碼框_內容被改變
輸入的密碼 ＝ 密碼框.內容
.子程序 _解鎖按鈕_被單擊
.如果 (輸入的密碼 ＝ 設置的密碼)
退出按鈕.禁止 ＝ 假
設置按鈕.禁止 ＝ 假
總在最前 ＝ 假
鎖鍵 (97, 0, 0, 0)
取消鼠標限制 (0)
退出按鈕.獲取焦點 ()
.否則
密碼框.獲取焦點 ()
.如果結束
.子程序 _設置按鈕_被單擊
載入 (設置窗口, _啟動窗口, 真)
.子程序 _退出按鈕_被單擊
結束 ()
.子程序 設置鼠標位置
.局部變量 RECT, 矩形區域
RECT.Left ＝ _啟動窗口.左邊
RECT.Top ＝ _啟動窗口.頂邊 ＋ 30
RECT.Right ＝ _啟動窗口.左邊 ＋ 135
RECT.Bottom ＝ _啟動窗口.頂邊 ＋ 128
限制鼠標 (RECT)
.版本 2
.程序集 窗口程序集2
.程序集變量 密碼1, 文本型
.程序集變量 密碼2, 文本型
.程序集變量 是否開機運行, 整數型, , , 0為否，1為是
.程序集變量 設置的密碼, 文本型
.子程序 _設置窗口_創建完畢
設置的密碼 ＝ 取文本註冊表項 (“SYSTEMSET”, “SET”, “PMM”, “”)
是否開機運行 ＝ 取數值註冊表項 (“SYSTEMSET”, “SET”, “BEGIN”, 0)
密碼編輯框1.內容 ＝ 設置的密碼
密碼編輯框2.內容 ＝ 設置的密碼
.如果 (是否隱藏窗口 ＝ 1)
桌面選擇框.選中 ＝ 真
.否則
桌面選擇框.選中 ＝ 假
.如果結束
.如果 (是否開機運行 ＝ 1)
運行選擇框.選中 ＝ 真
.否則
運行選擇框.選中 ＝ 假
.如果結束
.子程序 _密碼編輯框1_內容被改變
密碼1 ＝ 密碼編輯框1.內容
.子程序 _密碼編輯框2_內容被改變
密碼2 ＝ 密碼編輯框2.內容
.子程序 _桌面選擇框_被單擊
.如果 (是否隱藏窗口 ＝ 0)
桌面選擇框.選中 ＝ 真
是否隱藏窗口 ＝ 1
.否則
桌面選擇框.選中 ＝ 假
是否隱藏窗口 ＝ 0
.如果結束
.子程序 _運行選擇框_被單擊
.如果 (是否開機運行 ＝ 0)
運行選擇框.選中 ＝ 真
是否開機運行 ＝ 1
.否則
運行選擇框.選中 ＝ 假
是否開機運行 ＝ 0
.如果結束
.子程序 _保存按鈕_被單擊
.如果 (密碼1 ＝ 密碼2)
寫註冊表項 (“SYSTEMSET”, “SET”, “PMM”, 密碼1)
寫註冊表項 (“SYSTEMSET”, “SET”, “DESK”, 是否隱藏窗口)
寫註冊表項 (“SYSTEMSET”, “SET”, “BEGIN”, 是否開機運行)
.如果 (是否開機運行 ＝ 1)
寫註冊項 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\systemkey”, 取運行目錄 () ＋ “\” ＋ 取執行文件名 ())
.否則
刪除註冊項 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\systemkey”)
.如果結束
銷毀 ()
.否則
信息框 (“確認密碼不符！”, #警告圖標, “密碼錯誤！”)
密碼編輯框2.獲取焦點 ()
.如果結束
.子程序 _取消按鈕_被單擊
銷毀 ()
.版本 2
.數據類型 矩形區域
.成員 Left, 整數型
.成員 Top, 整數型
.成員 Right, 整數型
.成員 Bottom, 整數型