.DLL命令 _發送消息, 整數型, , "SendMessageA"
.參數 窗口句柄, 整數型
.參數 標識, 整數型
.參數 消息1, 整數型
.參數 消息2, 文本型
.DLL命令 _發送消息A, 整數型, , "SendMessageA"
.參數 窗口句柄, 整數型
.參數 標識, 整數型
.參數 消息1, 整數型
.參數 消息2, 整數型
.DLL命令 模擬鍵盤行動_, 整數型, "user32.dll", "keybd_event", , 這個函數模擬了鍵盤行動
.參數 鍵代碼, 整數型, , bVk,欲模擬的虛擬鍵碼
.參數 鍵掃描碼, 整數型, , bScan,鍵的OEM掃描碼
.參數 標誌值, 整數型, , dwFlags,標誌常數
.參數 特定值, 整數型, , dwExtraInfo,通常不用的壹個值
.DLL命令 _投遞消息, , , "PostMessageA", , 向指定窗口句柄發送消息
.參數 h
.參數 m
.參數 p
.參數 p
.版本 2
.程序集 程序集1
.子程序 _啟動子程序, 整數型, , 請在本子程序中放置易模塊初始化代碼
_臨時子程序 () ' 在初始化代碼執行完畢後調用測試代碼
返回 (0) ' 可以根據您的需要返回任意數值
.子程序 _臨時子程序
' 本名稱子程序用作測試程序用，僅在開發及調試環境中有效，編譯發布程序前將被系統自動清空，請將所有用作測試的臨時代碼放在本子程序中。 ***註意不要修改本子程序的名稱、參數及返回值類型。
.子程序 文本投遞, , 公開, 向指定窗口句柄的窗口中後臺發送文本內容,對遊戲有效!(無返回值)
.參數 窗口句柄, 整數型, , 接收消息的窗口句柄
.參數 文本內容, 文本型, , 發送的文本內容
.局部變量 消息, 字節集
.局部變量 長度, 整數型
.局部變量 計次, 整數型
消息 ＝ 到字節集 (文本內容)
長度 ＝ 取字節集長度 (消息)
.計次循環首 (長度, 計次)
_投遞消息 (窗口句柄, 258, 消息 [計次], 0)
.計次循環尾 ()
.子程序 文本發送, , 公開, 向指定編輯框後臺發送文本內容(無返回值)
.參數 臨時句柄, 整數型, , 接收消息的編輯框的句柄
.參數 臨時內容, 文本型, , 發送的文本內容
_發送消息A (臨時句柄, 177, 0, -1)
_發送消息 (臨時句柄, 194, 1, 臨時內容)
.子程序 按鍵消息, , 公開, 向指定窗口句柄的窗口中發送按鍵消息(無返回值)
.參數 窗口句柄, 整數型, , 接收消息的窗口句柄
.參數 鍵代碼, 整數型, , 按鍵的鍵代碼
.參數 狀態, 整數型, 可空, 可空:按鍵(按下+放開) 1 輸入字符 3 #按下 4 #放開
.參數 是否功能鍵, 邏輯型, 可空, 可空為假:普通鍵 真:功能鍵 (為功能鍵可用於熱鍵技能不輸入字符)
.局部變量 按下, 整數型
.局部變量 放開, 整數型
.如果 (是否功能鍵)
按下 ＝ 260
放開 ＝ 261
.否則
按下 ＝ 256
放開 ＝ 257
.如果結束
.如果真 (狀態 ＝ 1)
_投遞消息 (窗口句柄, 258, 鍵代碼, 0)
返回 ()
.如果真結束
.如果真 (狀態 ≠ 4)
_投遞消息 (窗口句柄, 按下, 鍵代碼, 0)
.如果真結束
.如果真 (狀態 ≠ 3)
_投遞消息 (窗口句柄, 放開, 鍵代碼, 0)
.如果真結束
返回 ()
.子程序 按鍵組合消息, , 公開, 向指定窗口句柄的窗口中發送組合按鍵的消息,遊戲中有效!(無返回值)
.參數 窗口句柄, 整數型, , 接收消息的窗口句柄
.參數 鍵代碼, 整數型, , 按鍵的鍵代碼
.參數 功能鍵碼1, 整數型, , 功能鍵的鍵代碼
.參數 功能鍵碼2, 整數型, 可空, 功能鍵的鍵代碼(可選)
.參數 功能鍵碼3, 整數型, 可空, 功能鍵的鍵代碼(可選)
.如果真 (功能鍵碼3 ≠ 0)
_投遞消息 (窗口句柄, 260, 功能鍵碼3, 0) ' 按下
.如果真結束
.如果真 (功能鍵碼2 ≠ 0)
_投遞消息 (窗口句柄, 260, 功能鍵碼2, 0) ' 按下
.如果真結束
_投遞消息 (窗口句柄, 260, 功能鍵碼1, 0) ' 按下
_投遞消息 (窗口句柄, 256, 鍵代碼, 0) ' 按下
.如果真 (功能鍵碼3 ≠ 0)
_投遞消息 (窗口句柄, 261, 功能鍵碼3, 0) ' 放開
.如果真結束
.如果真 (功能鍵碼2 ≠ 0)
_投遞消息 (窗口句柄, 261, 功能鍵碼2, 0) ' 放開
.如果真結束
_投遞消息 (窗口句柄, 261, 功能鍵碼1, 0) ' 放開
_投遞消息 (窗口句柄, 257, 鍵代碼, 0) ' 放開
.子程序 按鍵, , 公開, 執行模擬按鍵(無返回值)
.參數 鍵代碼, 整數型, , 鍵代碼
.參數 狀態, 整數型, 可空, 可空:按鍵(按下+放開) 3 #按下 4 #放開
.如果真 (狀態 ≠ 4)
模擬鍵盤行動_ (鍵代碼, 0, 0, 0)
.如果真結束
.如果真 (狀態 ≠ 3)
模擬鍵盤行動_ (鍵代碼, 0, 2, 0)
.如果真結束
' 按鍵 標記(按下 放開) 虛擬碼
' 通常 0 128
' home鍵區 1 129 33UP 34Down 35End 36Home 45Ins 46Del
' 光標區 1 129 37左 38上 39右 40下
' win鍵 1 129 91左 92右
' 菜單鍵 1 129 93
' print鍵 1 129 44
' 右CTRL鍵 1 129 163
' 右SHIFT鍵 1 129 161
' 右回車鍵 1 129 13
' Numlock鍵 1 129 144
' /(小鍵區) 1 129 111
' 左ALT鍵 32 128 164
' 右ALT鍵 33 129 165