VB 的CRC 校驗程序 請看下的URL!
VB下如何編寫CRC校驗程序
摘自於網絡
VB下如何編寫CRC校驗程序
隨著計算機技術的不斷發展，在現代工業中，利用微機進行數據通訊的工業控制應用得也越來越廣泛。由於傳輸距離、現場狀況等諸多可能出現的因素影響，計算機與受控設備之間的通訊數據常會發生無法預測的錯誤。為了防止錯誤所帶來的影響，壹般在通訊時采取數據校驗的辦法，而循環冗余碼校驗是最常用的校驗方法之壹。
壹、循環冗余碼校驗原理
循環冗余碼校驗英文名稱為Cyclical Redundancy Check，簡稱CRC。它是利用除法及余數的原理來作錯誤偵測（Error Detecting）的。實際應用時，發送裝置計算出CRC值並隨數據壹同發送給接收裝置，接收裝置對收到的數據重新計算CRC並與收到的CRC相比較，若兩個CRC值不同，則說明數據通訊出現錯誤。
根據應用環境與習慣的不同，CRC又可分為以下幾種標準：
①CRC-12碼；
②CRC-16碼；
③CRC-CCITT碼；
④CRC-32碼。
CRC-12碼通常用來傳送6-bit字符串。CRC-16及CRC-CCITT碼則用是來傳送8-bit字符，其中CRC-16為美國采用，而CRC-CCITT為歐洲國家所采用。CRC-32碼大都被采用在壹種稱為Point-to-Point的同步傳輸中。
下面以最常用的CRC-16為例來說明其生成過程。
CRC-16碼由兩個字節構成，在開始時CRC寄存器的每壹位都預置為1，然後把CRC寄存器與8-bit的數據進行異或，之後對CRC寄存器從高到低進行移位，在最高位（MSB）的位置補零，而最低位（LSB，移位後已經被移出CRC寄存器）如果為1，則把寄存器與預定義的多項式碼進行異或，否則如果 LSB為零，則無需進行異或。重復上述的由高至低的移位8次，第壹個8-bit數據處理完畢，用此時CRC寄存器的值與下壹個8-bit數據異或並進行如前壹個數據似的8次移位。所有的字符處理完成後CRC寄存器內的值即為最終的CRC值。
下面為CRC的計算過程：
1．設置CRC寄存器，並給其賦值FFFF(hex)。
2．將數據的第壹個8-bit字符與16位CRC寄存器的低8位進行異或，並把結果存入CRC寄存器。
3．CRC寄存器向右移壹位，MSB補零，移出並檢查LSB。
4．如果LSB為0，重復第三步；若LSB為1，CRC寄存器與多項式碼相異或。
5．重復第3與第4步直到8次移位全部完成。此時壹個8-bit數據處理完畢。
6．重復第2至第5步直到所有數據全部處理完成。
7．最終CRC寄存器的內容即為CRC值。
二、 循環冗余碼校驗程序的編寫
明白了CRC校驗碼的產生過程，編寫起程序來就非常容易了。由於Visual Basic的廣泛普及以及其在數據通訊中的重要地位，下面就以VB語言來編寫CRC的生成程序，其它語言只需稍做修改即可。
編寫CRC校驗程序有兩種辦法：壹種為計算法，壹種為查表法。下面對兩種方法分別討論。
1．計算法
計算法就是依據CRC校驗碼的產生原理來設計程序。其優點是模塊代碼少，修改靈活，可移植性好。其缺點為計算量大。為了便於理解，這裏假定了三位數據，而多項式碼為A001(hex)。
在窗體上放置壹命令按鈕Command1，並添加如下代碼：
Private Sub Command1_Click()
Dim CRC() As Byte
Dim d() As Byte ’待傳輸數據
ReDim d(2) As Byte
d(0) = 123
d(1) = 112
d(2) = 135
CRC = CRC16(d) ’調用CRC16計算函數
’CRC(0)為高位
’CRC(1)為低位
End Sub
註意：在數據傳輸時CRC的低位可能在前，而高位在後。
Function CRC16(data() As Byte) As String
Dim CRC16Lo As Byte, CRC16Hi As Byte ’CRC寄存器
Dim CL As Byte, CH As Byte ’多項式碼&HA001
Dim SaveHi As Byte, SaveLo As Byte
Dim I As Integer
Dim Flag As Integer
CRC16Lo = &HFF
CRC16Hi = &HFF
CL = &H1
CH = &HA0
For I = 0 To Ubound(data)
CRC16Lo = CRC16Lo Xor data(I) ’每壹個數據與CRC寄存器進行異或
For Flag = 0 To 7
SaveHi = CRC16Hi
SaveLo = CRC16Lo
CRC16Hi = CRC16Hi \ 2 ’高位右移壹位
CRC16Lo = CRC16Lo \ 2 ’低位右移壹位
If ((SaveHi And &H1) = &H1) Then ’如果高位字節最後壹位為1
CRC16Lo = CRC16Lo Or &H80 ’則低位字節右移後前面補1
End If ’否則自動補0
If ((SaveLo And &H1) = &H1) Then ’如果LSB為1，則與多項式碼進行異或
CRC16Hi = CRC16Hi Xor CH
CRC16Lo = CRC16Lo Xor CL
End If
Next Flag
Next I
Dim ReturnData(1) As Byte
ReturnData(0) = CRC16Hi ’CRC高位
ReturnData(1) = CRC16Lo ’CRC低位
CRC16 = ReturnData
End Function
2．查表法
查表法的優缺點與計算法的正好相反。為了便於比較，這裏所有的假定與計算法的完全相同，都而在窗體上放置壹個Command1的按鈕，其代碼部分與上面的也完全壹致。下面只介紹CRC函數的編寫源代碼。
Private Function CRC16(data() As Byte) As String
Dim CRC16Hi As Byte
Dim CRC16Lo As Byte
CRC16Hi = &HFF
CRC16Lo = &HFF
Dim I As Integer
Dim iIndex As Long
For I = 0 To Ubound(data)
iIndex = CRC16Lo Xor data(I)
CRC16Lo = CRC16Hi Xor GetCRCLo(iIndex) ’低位處理
CRC16Hi = GetCRCHi(iIndex) ’高位處理
Next I
Dim ReturnData(1) As Byte
ReturnData(0) = CRC16Hi ’CRC高位
ReturnData(1) = CRC16Lo ’CRC低位
CRC16 = ReturnData
End Function
’CRC低位字節值表
Function GetCRCLo(Ind As Long) As Byte
GetCRCLo = Choose(Ind + 1, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, _
&H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40)
End Function
’CRC高位字節值表
Function GetCRCHi(Ind As Long) As Byte
GetCRCHi = Choose(Ind + 1, &H0, &HC0, &HC1, &H1, &HC3, &H3, &H2, &HC2, &HC6, &H6, &H7, &HC7, &H5, &HC5, &HC4, &H4, &HCC, &HC, &HD, &HCD, &HF, &HCF, &HCE, &HE, &HA, &HCA, &HCB, &HB, &HC9, &H9, &H8, &HC8, &HD8, &H18, &H19, &HD9, &H1B, &HDB, &HAD, &H1A, &H1E, &HDE, &HDF, &H1F, &HDD, &H1D, &H1C, &HDC, &H14, &HD4, &HD5, &H15, &HD7, &H17, &H16, &HD6, &HD2, &H12, &H13, &HD3, &H11, &HD1, &HD0, &H10, &HF0, &H30, &H31, &HF1, &H33, &HF3, &HF2, &H32, &H36, &HF6, &HF7, &H37, &HF5, &H35, &H34, &HF4, &H3C, &HFC, &HFD, &H3D, &HFF, &H3F, &H3E, &HFE, &HFA, &H3A, &H3B, &HFB, &H39, &HF9, &HF8, &H38, &H28, &HE8, &HE9, &H29, &HEB, &H2B, &H2A, &HEA, &HEE, &H2E, &H2F, &HEF, &H2D, &HED, &HEC, &H2C, &HE4, &H24, &H25, &HE5, &H27, &HE7, &HE6, &H26, &H22, &HE2, &HE3, &H23, &HE1, &H21, &H20, &HE0, &HA0, &H60, _
&H61, &HA1, &H63, &HA3, &HA2, &H62, &H66, &HA6, &HA7, &H67, &HA5, &H65, &H64, &HA4, &H6C, &HAC, &HAD, &H6D, &HAF, &H6F, &H6E, &HAE, &HAA, &H6A, &H6B, &HAB, &H69, &HA9, &HA8, &H68, &H78, &HB8, &HB9, &H79, &HBB, &H7B, &H7A, &HBA, &HBE, &H7E, &H7F, &HBF, &H7D, &HBD, &HBC, &H7C, &HB4, &H74, &H75, &HB5, &H77, &HB7, &HB6, &H76, &H72, &HB2, &HB3, &H73, &HB1, &H71, &H70, &HB0, &H50, &H90, &H91, &H51, &H93, &H53, &H52, &H92, &H96, &H56, &H57, &H97, &H55, &H95, &H94, &H54, &H9C, &H5C, &H5D, &H9D, &H5F, &H9F, &H9E, &H5E, &H5A, &H9A, &H9B, &H5B, &H99, &H59, &H58, &H98, &H88, &H48, &H49, &H89, &H4B, &H8B, &H8A, &H4A, &H4E, &H8E, &H8F, &H4F, &H8D, &H4D, &H4C, &H8C, &H44, &H84, &H85, &H45, &H87, &H47, &H46, &H86, &H82, &H42, &H43, &H83, &H41, &H81, &H80, &H40)
End Function
以上程序在Win98，VB6下調試通過。