________________________________________
DS18B20、 DS1822 “壹線總線”數字化溫度傳感器是DALLAS最新單線數字溫度傳感器， 同DS1820壹樣，DS18B20也 支持“壹線總線”接口，測量溫度範圍為 -55°C~+125°C，在-10~+85°C範圍內,精度為±0.5°C。DS1822的精度較差為± 2°C 。現場溫度直接以“壹線總線”的數字方式傳輸，大大提高了系統的抗幹擾性。適合於惡劣環境的現場溫度測量，與前壹代產品不同，新的產品支持3V~5.5V的電壓範圍，使系統設計更靈活、方便。而且新壹代產品更便宜，體積更小。
DS18B20可以程序設定9~12位的分辨率，精度為±0.5°C。可選更小的封裝方式，更寬的電壓適用範圍。分辨率設定，及用戶設定的報警溫度存儲在EEPROM中，掉電後依然保存。DS18B20的性能是新壹代產品中最好的！性能價格比也非常出色！ DS1822與 DS18B20軟件兼容，是DS18B20的簡化版本。省略了存儲用戶定義報警溫度、分辨率參數的EEPROM，精度降低為±2°C，適用於對性能要求不高，成本控制嚴格的應用，是經濟型產品。 繼“壹線總線”的早期產品後，DS1820開辟了溫度傳感器技術的新概念。DS18B20和DS1822使電壓、特性及封裝有更多的選擇，讓我們可以構建適合自己的經濟的測溫系統。
DS18B20的內部結構
DS18B20內部結構主要由四部分組成：64位光刻ROM、溫度傳感器、非揮發的溫度報警觸發器TH和TL、配置寄存器。DS18B20的管腳排列如下:
15元/只
DQ為數字信號輸入/輸出端；GND為電源地；VDD為外接供電電源輸入端（在寄生電源接線方式時接地）。
光刻ROM中的64位序列號是出廠前被光刻好的，它可以看作是該DS18B20的地址序列碼。64位光刻ROM的排列是：開始8位（28H）是產品類型標號，接著的48位是該DS18B20自身的序列號，最後8位是前面56位的循環冗余校驗碼（CRC=X8+X5+X4+1）。光刻ROM的作用是使每壹個DS18B20都各不相同，這樣就可以實現壹根總線上掛接多個DS18B20的目的。
DS18B20中的溫度傳感器可完成對溫度的測量，以12位轉化為例:用16位符號擴展的二進制補碼讀數形式提供，以0.0625℃/LSB形式表達，其中S為符號位。
這是12位轉化後得到的12位數據，存儲在18B20的兩個8比特的RAM中，二進制中的前面5位是符號位，如果測得的溫度大於0，這5位為0，只要將測到的數值乘於0.0625即可得到實際溫度；如果溫度小於0，這5位為1，測到的數值需要取反加1再乘於0.0625即可得到實際溫度。
例如+125℃的數字輸出為07D0H，+25.0625℃的數字輸出為0191H，-25.0625℃的數字輸出為FF6FH，-55℃的數字輸出為FC90H。
DS18B20溫度傳感器的存儲器
DS18B20溫度傳感器的內部存儲器包括壹個高速暫存RAM和壹個非易失性的可電擦除的E2RAM,後者存放高溫度和低溫度觸發器TH、TL和結構寄存器。
暫存存儲器包含了8個連續字節，前兩個字節是測得的溫度信息，第壹個字節的內容是溫度的低八位，第二個字節是溫度的高八位。第三個和第四個字節是TH、TL的易失性拷貝，第五個字節是結構寄存器的易失性拷貝，這三個字節的內容在每壹次上電復位時被刷新。第六、七、八個字節用於內部計算。第九個字節是冗余檢驗字節。
該字節各位的意義如下：
TM R1 R0 1 1 1 1 1
低五位壹直都是1 ，TM是測試模式位，用於設置DS18B20在工作模式還是在測試模式。在DS18B20出廠時該位被設置為0，用戶不要去改動。R1和R0用來設置分辨率，如下表所示：（DS18B20出廠時被設置為12位）
分辨率設置表:
R1 R0 分辨率 溫度最大轉換時間
0 0 9位 93.75ms
0 1 10位 187.5ms
1 0 11位 375ms
1 1 12位 750ms
根據DS18B20的通訊協議，主機控制DS18B20完成溫度轉換必須經過三個步驟：每壹次讀寫之前都要對DS18B20進行復位，復位成功後發送壹條ROM指令，最後發送RAM指令，這樣才能對DS18B20進行預定的操作。復位要求主CPU將數據線下拉500微秒，然後釋放，DS18B20收到信號後等待16～60微秒左右，後發出60～240微秒的存在低脈沖，主CPU收到此信號表示復位成功。
DS1820使用中註意事項
DS1820雖然具有測溫系統簡單、測溫精度高、連接方便、占用口線少等優點，但在實際應用中也應註意以下幾方面的問題：
(1)較小的硬件開銷需要相對復雜的軟件進行補償，由於DS1820與微處理器間采用串行數據傳送，因此，在對DS1820進行讀寫編程時，必須嚴格的保證讀寫時序，否則將無法讀取測溫結果。在使用PL/M、C等高級語言進行系統程序設計時，對DS1820操作部分最好采用匯編語言實現。
(2)在DS1820的有關資料中均未提及單總線上所掛DS1820數量問題，容易使人誤認為可以掛任意多個DS1820，在實際應用中並非如此。當單總線上所掛DS1820超過8個時，就需要解決微處理器的總線驅動問題，這壹點在進行多點測溫系統設計時要加以註意。
(3)連接DS1820的總線電纜是有長度限制的。試驗中，當采用普通信號電纜傳輸長度超過50m時，讀取的測溫數據將發生錯誤。當將總線電纜改為雙絞線帶屏蔽電纜時，正常通訊距離可達150m，當采用每米絞合次數更多的雙絞線帶屏蔽電纜時，正常通訊距離進壹步加長。這種情況主要是由總線分布電容使信號波形產生畸變造成的。因此，在用DS1820進行長距離測溫系統設計時要充分考慮總線分布電容和阻抗匹配問題。
(4)在DS1820測溫程序設計中，向DS1820發出溫度轉換命令後，程序總要等待DS1820的返回信號，壹旦某個DS1820接觸不好或斷線，當程序讀該DS1820時，將沒有返回信號，程序進入死循環。這壹點在進行DS1820硬件連接和軟件設計時也要給予壹定的重視。
測溫電纜線建議采用屏蔽4芯雙絞線，其中壹對線接地線與信號線，另壹組接VCC和地線，屏蔽層在源端單點接地。
本站實驗板實驗程序：
;這是關於DS18B20的讀寫程序,數據腳P2.2,晶振12MHZ
;溫度傳感器18B20匯編程序,采用器件默認的12位轉化,最大轉化時間750微秒
;可以將檢測到的溫度直接顯示到AT89C51開發實驗板的兩個數碼管上
;顯示溫度00到99度,很準確哦~~無需校正!
ORG 0000H
;單片機內存分配申明!
TEMPER_L EQU 29H;用於保存讀出溫度的低8位
TEMPER_H EQU 28H;用於保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標誌位
a_bit equ 20h ;數碼管個位數存放內存位置
b_bit equ 21h ;數碼管十位數存放內存位置
MAIN:
LCALL GET_TEMPER;調用讀溫度子程序
;進行溫度顯示,這裏我們考慮用網站提供的兩位數碼管來顯示溫度
;顯示範圍00到99度,顯示精度為1度
;因為12位轉化時每壹位的精度為0.0625度,我們不要求顯示小數所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得壹個新字節,這個字節就是實際測量獲得的溫度
MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL DISPLAY;調用數碼管顯示子程序
CPL P1.0
AJMP MAIN
; 這是DS18B20復位初始化子程序
INIT_1820:
SETB P3.5
NOP
CLR P3.5
;主機發出延時537微秒的復位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P3.5;然後拉高數據線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB P3.5,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標誌位,表示DS1820存在
CLR P1.7;檢查到DS18B20就點亮P1.7LED
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標誌位,表示DS1820不存在
CLR P1.1;點亮P1。1腳LED表示溫度傳感器通信失敗
LJMP TSR7
TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時壹段時間
TSR7:
SETB P3.5
RET
; 讀出轉換後的溫度值
GET_TEMPER:
SETB P3.5
LCALL INIT_1820;先復位DS18B20
JB FLAG1,TSS2
CLR P1.2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P1.3;DS18B20已經被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發出溫度轉換命令
LCALL WRITE_1820
;這裏通過調用顯示子程序實現延時壹段時間,等待AD轉換結束,12位的話750微秒
LCALL DISPLAY
LCALL INIT_1820;準備讀溫度前先復位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的溫度數據保存到35H/36H
CLR P1.4
RET
;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;壹***8位數據
CLR C
WR1:
CLR P3.5
MOV R3,#6
DJNZ R3,$
RRC A
MOV P3.5,C
MOV R3,#23
DJNZ R3,$
SETB P3.5
NOP
DJNZ R2,WR1
SETB P3.5
RET
; 讀DS18B20的程序,從DS18B20中讀出兩個字節的溫度數據
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數據壹***有8位
RE01:
CLR C
SETB P3.5
NOP
NOP
CLR P3.5
NOP
NOP
NOP
SETB P3.5
MOV R3,#9
RE10:
DJNZ R3,RE10
MOV C,P3.5
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET
;顯示子程序
display: mov a,29H;將29H中的十六進制數轉換成10進制
mov b,#10 ;10進制/10=10進制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數
MOVC A,@A+DPTR ;查個位數的7段代碼
mov p0,a ;送出個位的7段代碼
clr p2.0 ;開個位顯示
acall d1ms ;顯示1ms
setb p2.0
mov a,b_bit ;取十位數
MOVC A,@A+DPTR ;查十位數的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.1 ;開十位顯示
acall d1ms ;顯示1ms
setb p2.1
djnz r1,dplop ;100次沒完循環
djnz r0,dpl1 ;4個100次沒完循環
ret
;1MS延時(按12MHZ算)
D1MS: MOV R7,#80
DJNZ R7,$
RET
;實驗板上的7段數碼管0～9數字的***陰顯示代碼
numtab: DB 0F3H，0A4H，0B0H，99H，92H，82H，0F8H，80H，90H
end
以下是第二種采集和處理程序供網友參考
;溫度傳感器18B20匯編程序,采用器件默認的12位轉化,最大轉化時間750微秒
;將溫度數據通過串口發送出去，波特率2400
;本程序專為AT89C51實驗開發板編寫.適合12晶振
;本程序經過驗證,可以顯示溫度+/-和兩位整數溫度和兩位小數溫度數據
DOT EQU 30H
ZHENGSHU EQU 31H
FLAG1 EQU 38H ;是否檢測到DS18B20的標誌位
;定義溫度數據
DIS_1 EQU 32H ;符號
DIS_2 EQU 33H ;十位
DIS_3 EQU 34H ;個位
DIS_4 EQU 35H ;小數點後第壹位
DIS_5 EQU 36H ;小數點後第二位
WDDATA BIT P2.2 ;定義DS18B20的數據腳為P2.2端口
ORG 0000H
;以下為主程序進行CPU中斷方式設置
CLR EA ;關閉總中斷
MOV SCON,#50H ;設置成串口1方式
MOV TMOD,#20H ;波特率發生器T1工作在模式2上
MOV TH1,#0F3H ;預置初值(按照波特率2400BPS預置初值)
MOV TL1,#0F3H ;預置初值(按照波特率2400BPS預置初值)
SETB TR1 ;啟動定時器T1
;以上完成串口2400通訊初始化設置
;-------------------------
; 主程序
;-------------------------
MAIN:
LCALL INIT_1820 ;調用復位DS18B20子程序
MAIN1:
LCALL GET_TEMPER;調用讀溫度子程序
LCALL FORMULA ;通過公式計算,小數點後顯示兩位
LCALL BCD
LCALL DISPLAY ;調用串口顯示子程序
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
AJMP MAIN1
;-------------------------
; DS18B20復位初始化程序
;-------------------------
INIT_1820:
SETB WDDATA
NOP
CLR WDDATA
;主機發出延時540微秒的復位低脈沖
MOV R0,#36
LCALL DELAY
SETB WDDATA;然後拉高數據線
NOP
NOP
MOV R0,#36
TSR2:
JNB WDDATA,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標誌位,表示DS1820存在
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標誌位,表示DS1820不存在
LJMP TSR7
TSR5:
MOV R0,#06BH
TSR6:
DJNZ R0,TSR6 ;復位成功!時序要求延時壹段時間
TSR7:
SETB WDDATA
RET
;-------------------
; 讀出轉換後的溫度值
;-------------------
GET_TEMPER:
SETB WDDATA ; 定時入口
LCALL INIT_1820 ;先復位DS18B20
JB FLAG1,TSS2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發出溫度轉換命令
LCALL WRITE_1820
MOV R0,#50 ;等待AD轉換結束,12位的話750微秒.
LCALL DELAY
LCALL INIT_1820 ;準備讀溫度前先復位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的九個字節數據保存到60H-68H
RET
;----------------------------------
;寫DS18B20的子程序(有具體的時序要求)
;----------------------------------
WRITE_1820:
MOV R2,#8 ;壹***8位數據
CLR C
WR1:
CLR WDDATA
MOV R3,#6
DJNZ R3,$
RRC A
MOV WDDATA,C
MOV R3,#24
DJNZ R3,$
SETB WDDATA
NOP
DJNZ R2,WR1
SETB WDDATA
RET
;--------------------------------------------------
; 讀DS18B20的程序,從DS18B20中讀出九個字節的數據
;--------------------------------------------------
READ_18200:
MOV R4,#9
MOV R1,#60H ; 存入60H開始的九個單元
RE00:
MOV R2,#8
RE01:
CLR C
SETB WDDATA
NOP
NOP
CLR WDDATA
NOP
NOP
NOP
SETB WDDATA
MOV R3,#09
RE10:
DJNZ R3,RE10
MOV C,WDDATA
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
INC R1
DJNZ R4,RE00
RET
;------------------------
;溫度計算子程序
;------------------------
FORMULA: ; 按公式：T實際=(T整數-0.25)+( M每度-M剩余)/ M每度
;計算出實際溫度，整數部分和小數部分分別存於ZHENGSHU單元和DOT單元
;將61H中的低4位移入60H中的高4位，得到溫度的整數部分，並存於ZHENGSHU單元
MOV 29H,61H
MOV A,60H
MOV C,48H
RRC A
MOV C,49H
RRC A
MOV C,4AH
RRC A
MOV C,4BH
RRC A
MOV ZHENGSHU,A
; ( M每度-M剩余)/ M每度,小數值存於A中
MOV A,67h
SUBB A,66h
MOV B,#64H
MUL AB
MOV R4,B
MOV R5,A
MOV R7,67H
LCALL DIV457
MOV A,R3
;再減去0.25，實際應用中減去25
SUBB A,#19H
MOV DOT,A ;小數部分存於DOT中
MOV A,ZHENGSHU
SUBB A,#00H ;整數部分減去來自小數部分的借位
MOV ZHENGSHU,A
MOV C,4BH
JNC ZHENG ;是否為負數
CPL A
INC A
MOV DIS_1,#2DH ; 零度以下時,第壹位顯示"-"號
MOV ZHENGSHU,A
ZHENG:
MOV DIS_1,#2BH ; 零度以上時,第壹位顯示"+"號
RET
;------------------------
;雙字節除以單字節子程序
;------------------------
DIV457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ;商溢出
RET
DV50: MOV R6,#8 ;求平均值（R4R5／R7－→R3）
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ;四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
;---------------------
;轉換成非壓縮的BCD碼
;---------------------
BCD: MOV A,ZHENGSHU
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉換成ASCII碼
MOV DIS_2,A
MOV DIS_3,B
MOV A,DIS_3
ORL A,#00110000B ;轉換成ASCII碼
mov DIS_3,A
MOV A,DOT
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉換成ASCII碼
MOV DIS_4,A
MOV DIS_5,B
MOV A,DIS_5
ORL A,#00110000B ;轉換成ASCII碼
mov DIS_5,A
RET
;----------------------
;串口顯示數據子程序
;----------------------
DISPLAY:
CLR TI
MOV A,DIS_1
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示+/-
CLR TI
MOV A,DIS_2
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示整數第壹位
CLR TI
MOV A,DIS_3
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示整數第二位
CLR TI
MOV A,#2EH
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示小數點
CLR TI
MOV A,DIS_4
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示小數第壹位
CLR TI
MOV A,DIS_5
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示小數第壹位
CLR TI
MOV A,#0DH;換行
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示
CLR TI
MOV A,#0AH;換行
MOV SBUF,A
JNB TI,$ ;發送給PC,通過串口調試助手顯示
RET
;----------------------
;延時子程序
;----------------------
;為保證DS18B20的嚴格I/O時序，需要做較精確的延時
;在DS18B20操作中，用到的延時有15 μs，90 μs，270 μs，540 μs
;因這些延時均為15 μs的整數倍，因此可編寫壹個DELAY15（n）函數
DELAY: ;11.05962M晶振
LOOP: MOV R1,#06H
LOOP1: DJNZ R1,LOOP1
DJNZ R0,LOOP
RET
;500毫秒延時子程序，占用R4、R5
DELAY500:MOV R4,#248
DA222:MOV R5,#248
DJNZ R5,$
DJNZ R4,DA222
RET
END