這僅僅是壹個求已知矩陣的逆的自定義過程,具體的應用與實現,還是要妳自己去動手的.
我給告訴妳吧!
在窗體上添加壹個按鈕,復制下面的代碼就可以了.
Option Explicit
Private Sub Command1_Click()
Dim a(2, 2) As Double
Dim n As Integer
Dim d As Integer
Dim i As Integer
Dim j As Integer
Dim YesNo As Boolean
'產生壹個2*2的方陣A
d = 0
n = 2
For i = 1 To n
For j = 1 To n
d = d + 1
a(i, j) = d
Next j
Next i
'輸出矩陣A
For i = 1 To n
For j = 1 To n
Print a(i, j),
Next j
Next i
'調用自定義過程,求逆
YesNo = MRinv(n, a())
If YesNo Then
'輸出矩陣的逆
For i = 1 To n
For j = 1 To n
Print a(i, j),
Next j
Next i
Else
Print "不存在逆矩陣!"
End If
End Sub
Function MRinv(n As Integer, mtxA() As Double) As Boolean
' 局部變量
ReDim nIs(n) As Integer, nJs(n) As Integer
Dim i As Integer, j As Integer, k As Integer
Dim d As Double, p As Double
' 全選主元,消元
For k = 1 To n
d = 0#
For i = k To n
For j = k To n
p = Abs(mtxA(i, j))
If (p > d) Then
d = p
nIs(k) = i
nJs(k) = j
End If
Next j
Next i
' 求解失敗
If (d + 1# = 1#) Then
MRinv = False
Exit Function
End If
If (nIs(k) <> k) Then
For j = 1 To n
p = mtxA(k, j)
mtxA(k, j) = mtxA(nIs(k), j)
mtxA(nIs(k), j) = p
Next j
End If
If (nJs(k) <> k) Then
For i = 1 To n
p = mtxA(i, k)
mtxA(i, k) = mtxA(i, nJs(k))
mtxA(i, nJs(k)) = p
Next i
End If
mtxA(k, k) = 1# / mtxA(k, k)
For j = 1 To n
If (j <> k) Then mtxA(k, j) = mtxA(k, j) * mtxA(k, k)
Next j
For i = 1 To n
If (i <> k) Then
For j = 1 To n
If (j <> k) Then mtxA(i, j) = mtxA(i, j) - mtxA(i, k) * mtxA(k, j)
Next j
End If
Next i
For i = 1 To n
If (i <> k) Then mtxA(i, k) = -mtxA(i, k) * mtxA(k, k)
Next i
Next k
' 調整恢復行列次序
For k = n To 1 Step -1
If (nJs(k) <> k) Then
For j = 1 To n
p = mtxA(k, j)
mtxA(k, j) = mtxA(nJs(k), j)
mtxA(nJs(k), j) = p
Next j
End If
If (nIs(k) <> k) Then
For i = 1 To n
p = mtxA(i, k)
mtxA(i, k) = mtxA(i, nIs(k))
mtxA(i, nIs(k)) = p
Next i
End If
Next k
' 求解成功
MRinv = True
End Function